修改指标

 老师，请帮忙去掉底纹颜色，

DRAWGBK(O>C,RGB(0,58,58),RGB(0,58,58),0);
N:=21;
M1:=3;
M2:=3;

RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
BACKGROUNDSTYLE(1);
K:SMA(RSV,M1,1);
D:SMA(K,M2,1),COLORGREEN,LINETHICK1;

IF(K>REF(K,1),K,NULL),COLORRED,LINETHICK1;
IF(K<REF(K,1),K,NULL),COLORWHITE,LINETHICK1;

危险:100,COLORRED;
超买:80,COLORCYAN;
平衡:50,POINTDOT,COLORWHITE;
超卖:20,COLORYELLOW;
抄底:0,COLORBLUE;
DRAWTEXT(ISLASTBAR,危险,'-危险'),COLORRED,ALIGN0,VALIGN1;
DRAWTEXT(ISLASTBAR,超买,'-超买'),COLORCYAN,ALIGN0,VALIGN1;
DRAWTEXT(ISLASTBAR,平衡,'-平衡'),COLORWHITE,ALIGN0,VALIGN1;
DRAWTEXT(ISLASTBAR,超卖,'-超卖'),COLORYELLOW,ALIGN0,VALIGN1;
DRAWTEXT(ISLASTBAR,抄底,'-抄底'),COLORBLUE,ALIGN0,VALIGN1;

//——顶底背离——
//顶背离
//发生了死叉CROSS(D,K)
//倒数第一次金叉周期数，这个数求出来的是算上了死叉突破的第一根线，所以要-1才是金叉区间长度，但是在求最近金叉距当前点的X值时，就不要-1
FIRST_GOLD_LEN_A:=BARSLAST(CROSS(K,D));
//倒数第一次金叉到现在的最高价K线的周期数
FIRST_HIGH_C_BARS_A:=HHVBARS(C,FIRST_GOLD_LEN_A+1);
//倒数第一次金叉到现在的行情中的最高C
FIRST_HIGH_C_A:=REF(C,FIRST_HIGH_C_BARS_A);
//倒数第一次金叉最高DIFF到现在的K线的周期数
FIRST_HIGH_K_BARS_A:=HHVBARS(K,FIRST_GOLD_LEN_A+1);
//倒数第一次金叉最高DIFF值
FIRST_HIGH_K_A:=REF(K,FIRST_HIGH_K_BARS_A);

//倒数第一个死叉持续周期数
FIRST_DEAD_LEN_A:=REF(BARSLAST(CROSS(D,K)),FIRST_GOLD_LEN_A);
//倒数第二个金叉周期内的最高价格到其下一次死叉点的周期数
SECOND_HIGH_C_BARS_A:=REF(HHVBARS(C,FIRST_HIGH_C_BARS_A+1),FIRST_GOLD_LEN_A+FIRST_DEAD_LEN_A);
//倒数第二个金叉周期内的最高价格
SECOND_HIGH_C_A:=REF(C,SECOND_HIGH_C_BARS_A+FIRST_GOLD_LEN_A+FIRST_DEAD_LEN_A);
//倒数第二个金叉周期内的最高DIFF到其下一次死叉点的周期数
SECOND_HIGH_K_BARS_A:=REF(HHVBARS(K,FIRST_HIGH_K_BARS_A+1),FIRST_GOLD_LEN_A+FIRST_DEAD_LEN_A);
//倒数第二个金叉期间的最高DIFF
SECOND_HIGH_K_A:=REF(K,SECOND_HIGH_K_BARS_A+FIRST_GOLD_LEN_A+FIRST_DEAD_LEN_A);

//倒数第二个金叉持续周期数
SECOND_GOLD_LEN_A:=REF(BARSLAST(CROSS(K,D)),FIRST_GOLD_LEN_A+FIRST_DEAD_LEN_A);
//倒数第二个死叉持续周期数
SECOND_DEAD_LEN_A:=REF(BARSLAST(CROSS(D,K)),FIRST_GOLD_LEN_A+FIRST_DEAD_LEN_A+SECOND_GOLD_LEN_A);
//倒数第三个金叉内的最高C位置
THIRD_HIGH_C_BARS_A:=REF(HHVBARS(C,FIRST_HIGH_C_BARS_A+1),FIRST_GOLD_LEN_A+FIRST_DEAD_LEN_A+SECOND_GOLD_LEN_A+SECOND_DEAD_LEN_A);
//倒数第三个金叉周期内的最高价格
THIRD_HIGH_C_A:=REF(C,FIRST_GOLD_LEN_A+FIRST_DEAD_LEN_A+SECOND_GOLD_LEN_A+SECOND_DEAD_LEN_A+THIRD_HIGH_C_BARS_A);
//倒数第三个金叉周期内的最高DIFF到其下一次死叉点的周期数
THIRD_HIGH_K_BARS_A:=REF(HHVBARS(K,FIRST_HIGH_K_BARS_A+1),FIRST_GOLD_LEN_A+FIRST_DEAD_LEN_A+SECOND_GOLD_LEN_A+SECOND_DEAD_LEN_A);
//倒数第三个金叉期间的最高DIFF
THIRD_HIGH_K_A:=REF(K,FIRST_GOLD_LEN_A+FIRST_DEAD_LEN_A+SECOND_GOLD_LEN_A+SECOND_DEAD_LEN_A+THIRD_HIGH_K_BARS_A);

//顶背离 发生死叉的时候最近顶和前一次顶 价格上升  DIFF下降
DINGBEI:=CROSS(D,K) && FIRST_HIGH_C_A >= SECOND_HIGH_C_A && FIRST_HIGH_K_A < SECOND_HIGH_K_A;
KD顶背:=IF(DINGBEI>0,0.1,0),COLOR00FF00,POINTDOT;
//DRAWTEXT(KD顶背>0,K+0.4,'顶背离'),COLORRED;
//隔峰背离
//价格相继提升
GF_PRICE:=FIRST_HIGH_C_A>SECOND_HIGH_C_A && SECOND_HIGH_C_A > THIRD_HIGH_C_A;
//DIFF12不背 23背 13背
GF_K:=FIRST_HIGH_K_A > SECOND_HIGH_K_A && SECOND_HIGH_K_A < THIRD_HIGH_K_A && FIRST_HIGH_K_A < THIRD_HIGH_K_A;
GFDINGBEI:=CROSS(D,K) && GF_PRICE && GF_K;
隔峰顶背:=IF(GFDINGBEI>0,0.1,0),COLOR00FF00,POINTDOT;

//连续顶背
DINGBEI2:=SECOND_HIGH_C_A >= THIRD_HIGH_C_A && SECOND_HIGH_K_A < THIRD_HIGH_K_A;
连续顶背:IF(DINGBEI&&DINGBEI2>0,0.1,0),COLOR00FF00,POINTDOT;

DRAWTEXT((隔峰顶背=0 && 连续顶背=0)&&KD顶背>0,K+7,'顶背离'),COLORYELLOW;
DRAWTEXT(连续顶背>0,K+7,'连续顶背'),COLORYELLOW;
DRAWTEXT(隔峰顶背>0,K+7,'隔峰顶背'),COLORYELLOW;

//——底背离——
//底背离
//发生了金叉CROSS(K,D)
//倒数第一次死叉周期数，这个数求出来的是算上了金叉突破的第一根线，所以要-1才是死叉区间长度，但是在求最近死叉距当前点的X值时，就不要-1
FIRST_DEAD_LEN_B:=BARSLAST(CROSS(D,K));
//倒数第一次死叉到现在的最低价K线的周期数
FIRST_LOW_C_BARS_B:=LLVBARS(C,FIRST_DEAD_LEN_B+1);
//倒数第一次死叉到现在的行情中的最低C
FIRST_LOW_C_B:=REF(C,FIRST_LOW_C_BARS_B);
//倒数第一次死叉最低DIFF到现在的K线的周期数
FIRST_LOW_K_BARS_B:=LLVBARS(K,FIRST_DEAD_LEN_B+1);
//倒数第一次死叉最低DIFF值
FIRST_LOW_K_B:=REF(K,FIRST_LOW_K_BARS_B);

//倒数第一个金叉持续周期数
FIRST_GOLD_LEN_B:=REF(BARSLAST(CROSS(K,D)),FIRST_DEAD_LEN_B);
//倒数第二个死叉周期内的最低价格到其下一次金叉点的周期数
SECOND_LOW_C_BARS_B:=REF(LLVBARS(C,FIRST_LOW_C_BARS_B+1),FIRST_DEAD_LEN_B+FIRST_GOLD_LEN_B);
//倒数第二个死叉周期内的最低价格
SECOND_LOW_C_B:=REF(C,SECOND_LOW_C_BARS_B+FIRST_DEAD_LEN_B+FIRST_GOLD_LEN_B);
//倒数第二个死叉周期内的最低DIFF到其下一次金叉点的周期数
SECOND_LOW_K_BARS_B:=REF(LLVBARS(K,FIRST_LOW_K_BARS_B+1),FIRST_DEAD_LEN_B+FIRST_GOLD_LEN_B);
//倒数第二个死叉期间的最低DIFF
SECOND_LOW_K_B:=REF(K,SECOND_LOW_K_BARS_B+FIRST_DEAD_LEN_B+FIRST_GOLD_LEN_B);

//倒数第二个死叉持续周期数
SECOND_DEAD_LEN_B:=REF(BARSLAST(CROSS(D,K)),FIRST_DEAD_LEN_B+FIRST_GOLD_LEN_B);
//倒数第二个金叉持续周期数
SECOND_GOLD_LEN_B:=REF(BARSLAST(CROSS(K,D)),FIRST_DEAD_LEN_B+FIRST_GOLD_LEN_B+SECOND_DEAD_LEN_B);
//倒数第三个死叉内的最低C位置
THIRD_LOW_C_BARS_B:=REF(LLVBARS(C,FIRST_LOW_C_BARS_B+1),FIRST_DEAD_LEN_B+FIRST_GOLD_LEN_B+SECOND_DEAD_LEN_B+SECOND_GOLD_LEN_B);
//倒数第三个死叉周期内的最低价格
THIRD_LOW_C_B:=REF(C,FIRST_DEAD_LEN_B+FIRST_GOLD_LEN_B+SECOND_DEAD_LEN_B+SECOND_GOLD_LEN_B+THIRD_LOW_C_BARS_B);
//倒数第三个死叉周期内的最低DIFF到其下一次金叉点的周期数
THIRD_LOW_K_BARS_B:=REF(LLVBARS(K,FIRST_LOW_K_BARS_B+1),FIRST_DEAD_LEN_B+FIRST_GOLD_LEN_B+SECOND_DEAD_LEN_B+SECOND_GOLD_LEN_B);
//倒数第三个死叉期间的最低DIFF
THIRD_LOW_K_B:=REF(K,FIRST_DEAD_LEN_B+FIRST_GOLD_LEN_B+SECOND_DEAD_LEN_B+SECOND_GOLD_LEN_B+THIRD_LOW_K_BARS_B);

//底背离 发生金叉的时候最近底和前一次底 价格下降  DIFF上升
DIBEI:=CROSS(K,D) && FIRST_LOW_C_B <= SECOND_LOW_C_B && FIRST_LOW_K_B > SECOND_LOW_K_B;
KD底背:=IF(DIBEI>0,0.1,0),COLORRED,POINTDOT;
//DRAWTEXT(MACD底背>0,DEA-0.8,'底背离'),COLORRED;
//隔峰背离
//价格相继提升
GF_PRICE_B:=FIRST_LOW_C_B<SECOND_LOW_C_B && SECOND_LOW_C_B < THIRD_LOW_C_B;
//DIFF12不背 23背 13背
GF_K_B:=FIRST_LOW_K_B < SECOND_LOW_K_B && SECOND_LOW_K_B > THIRD_LOW_K_B && FIRST_LOW_K_B > THIRD_LOW_K_B;
GFDIBEI:=CROSS(K,D) && GF_PRICE_B && GF_K_B;

//连续底背
DIBEI2:=SECOND_LOW_C_B <= THIRD_LOW_C_B && SECOND_LOW_K_B > THIRD_LOW_K_B;
连续底背:IF(DIBEI&&DIBEI2>0,0.1,0),COLORRED,POINTDOT;
隔峰底背:=IF(GFDIBEI>0,0.1,0),COLORRED,POINTDOT;

DRAWTEXT((连续底背=0 && 隔峰底背=0)&&KD底背>0,K-7,'底背离'),COLORGREEN;
DRAWTEXT(连续底背>0,D-7,'连续底背'),COLORGREEN;
DRAWTEXT(隔峰底背>0,D-7,'隔峰底背'),COLORGREEN;

PLAYSOUND((隔峰顶背=0 && 连续顶背=0)&&KD顶背>0,'F');//当条件满足时，播放声音'N'
PLAYSOUND(连续顶背>0,'F');//当条件满足时，播放声音'N'
PLAYSOUND(隔峰顶背>0,'F');//当条件满足时，播放声音'N'

PLAYSOUND((连续底背=0 && 隔峰底背=0)&&KD底背>0,'E');//当条件满足时，播放声音'N'
PLAYSOUND(连续底背>0,'E');//当条件满足时，播放声音'N'
PLAYSOUND(隔峰底背>0,'E');//当条件满足时，播放声音'N'

（来源：文华财经）